今天我們來說說ESP32 for Arduino 的雙核。

ESP32的雙核

ESP32上是有兩個(gè)核心的，配備了2個(gè) Xtensa 32 位 LX6 微處理器：核心0和核心1，默認(rèn)是運(yùn)行在核心1的，我們可以在代碼中創(chuàng)建一個(gè)任務(wù)在核心0上面運(yùn)行，進(jìn)行并行的多任務(wù)處理。

我們看一下官方的芯片資源框圖，這里是有兩個(gè)Core的：

我們可以通過一個(gè)函數(shù)來識別代碼在哪個(gè)內(nèi)核中運(yùn)行

xPortGetCoreID()

這個(gè)函數(shù)會返回運(yùn)行的Core ID號。

我們通過以下代碼測試一下

void setup() {
  Serial.begin(115200);
  Serial.print("setup() running on core ");
  Serial.println(xPortGetCoreID());
}

void loop() {
  Serial.print("loop() running on core ");
  Serial.println(xPortGetCoreID());
}

我們看一下打印的情況

Arduino for ESP32是運(yùn)行在FreeRTOS實(shí)時(shí)操作系統(tǒng)上的，我們的loop()函數(shù)就是內(nèi)核1的一個(gè)任務(wù)，我們在創(chuàng)建任務(wù)的時(shí)候，可以指定運(yùn)行在哪個(gè)核心。下面的需要一點(diǎn)FreeRTOS的基礎(chǔ)，如果沒接觸的可以先自行了解一下，這里推薦野火的《FreeRTOS內(nèi)核實(shí)現(xiàn)與應(yīng)用開發(fā)實(shí)戰(zhàn)指南》這本書，講的非常棒！

新建任務(wù)

創(chuàng)建任務(wù)句柄

我們這里創(chuàng)建一個(gè)Task1

TaskHandle_t Task1;

創(chuàng)建任務(wù)

設(shè)置任務(wù)的執(zhí)行函數(shù)，優(yōu)先級，堆棧大小，運(yùn)行在哪個(gè)內(nèi)核等參數(shù)

xTaskCreatePinnedToCore(
      Task1code, /* Function to implement the task */
      "Task1", /* Name of the task */
      10000,  /* Stack size in words */
      NULL,  /* Task input parameter */
      0,  /* Priority of the task */
      &Task1,  /* Task handle. */
      0); /* Core where the task should run */

具體的任務(wù)函數(shù)

這里是一個(gè)無限循環(huán)，任務(wù)1的代碼在這里實(shí)現(xiàn)，然后每隔一段時(shí)間片，就去執(zhí)行當(dāng)前更高優(yōu)先級的任務(wù)。

Void Task1code( void * parameter) {
  for(;;) {
    Code for task 1 
    (...)
  }
}

任務(wù)刪除

vTaskDelete(Task1);

多任務(wù)案例

下面的代碼，我們以不同的時(shí)間讓LED燈閃爍，然后Task1運(yùn)行在core0，Task運(yùn)行在core1。

/*
 *      Created on: 20220316      
 *      Author:     公眾號：跳動(dòng)的字節(jié)
 *      Function    12 ESP32的雙核
 *      Version:    V1.0
 *
 *                        ,%%%%%%%%,
 *                      ,%%/%%%%/%%
 *                     ,%%%c''''J/%%%
 *           %.        %%%%/ o  o %%%
 *           `%%.      %%%%       |%%%
 *            `%%      `%%%%(__Y__)%%'
 *            //        ;%%%%`-/%%%'
 *            ((      /   `%%%%%%%'
 *                  .'           |
 *                 /          | |
 *               /          ) | |
 *                          /_ | |__
 *                (____________))))))) 攻城獅
 *
 */
 
TaskHandle_t Task1;
TaskHandle_t Task2;

// LED pins
const int led1 = 2;
const int led2 = 4;

void setup() {
  Serial.begin(115200); 
  pinMode(led1, OUTPUT);
  pinMode(led2, OUTPUT);

  //create a task that will be executed in the Task1code() function, with priority 1 and executed on core 0
  xTaskCreatePinnedToCore(
                    Task1code,   /* Task function. */
                    "Task1",     /* name of task. */
                    10000,       /* Stack size of task */
                    NULL,        /* parameter of the task */
                    1,           /* priority of the task */
                    &Task1,      /* Task handle to keep track of created task */
                    0);          /* pin task to core 0 */                  
  delay(500); 

  //create a task that will be executed in the Task2code() function, with priority 1 and executed on core 1
  xTaskCreatePinnedToCore(
                    Task2code,   /* Task function. */
                    "Task2",     /* name of task. */
                    10000,       /* Stack size of task */
                    NULL,        /* parameter of the task */
                    1,           /* priority of the task */
                    &Task2,      /* Task handle to keep track of created task */
                    1);          /* pin task to core 1 */
    delay(500); 
}

//Task1code: blinks an LED every 1000 ms
void Task1code( void * pvParameters ){
  Serial.print("Task1 running on core ");
  Serial.println(xPortGetCoreID());

  for(;;){
    digitalWrite(led1, HIGH);
    delay(1000);
    digitalWrite(led1, LOW);
    delay(1000);
  } 
}

//Task2code: blinks an LED every 500 ms
void Task2code( void * pvParameters ){
  Serial.print("Task2 running on core ");
  Serial.println(xPortGetCoreID());

  for(;;){
    digitalWrite(led2, HIGH);
    delay(500);
    digitalWrite(led2, LOW);
    delay(500);
  }
}

void loop() {
  
}

實(shí)際效果

串口打?。?/p>

硬件連接非常簡單，IO2與IO4各接一個(gè)LED燈即可，我們看看效果：

led1每1秒閃爍一次，led2每500ms閃爍一次，這樣就是真正的兩個(gè)內(nèi)核同時(shí)運(yùn)行兩個(gè)不同的任務(wù)。

到這里，12篇基礎(chǔ)教程已經(jīng)講完了，大家對ESP32也有所了解了，接下來我們講進(jìn)階教程，開始玩起WiFi和藍(lán)牙以及各種傳感器以及屏幕等，有了WiFi，我們就可以與外界進(jìn)行通信，能做一些超級好玩的項(xiàng)目。

感謝大家，關(guān)于ESP32的學(xué)習(xí)，希望大家Enjoy!