adc0832引腳圖:ADC0832 是美國國家半導(dǎo)體公司生產(chǎn)的一種8 位分辨率、雙通道A/D轉(zhuǎn)換
芯片。由于它體積小，兼容性強，性價比高而深受單片機愛好者及企業(yè)歡迎，
其目前已經(jīng)有很高的普及率。學(xué)習(xí)并使用ADC0832 可是使我們了解A/D轉(zhuǎn)換器
的原理，有助于我們單片機技術(shù)水平的提高。
ADC0832 具有以下特點：
· 8位分辨率；
· 雙通道A/D轉(zhuǎn)換；
· 輸入輸出電平與TTL/CMOS相兼容；
· 5V電源供電時輸入電壓在0~5V之間；
· 工作頻率為250KHZ，轉(zhuǎn)換時間為32μS；
· 一般功耗僅為15mW；
· 8P、14P—DIP（雙列直插）、PICC 多種封裝；
· 商用級芯片溫寬為0°C to +70°C，工業(yè)級芯片溫寬為−40°C to +85°C；
芯片頂視圖：（圖1、圖2）

ADC0832程序:

程序占用資源有累加器A，工作寄存器R7,
通用寄存器B 和特殊寄存器CY。通道功能寄
存器和轉(zhuǎn)換值共用寄存器B。在使用轉(zhuǎn)換子程
序之前必須確定通道功能寄存器B 的值，其賦
值語句為“MOV B,#data”（00H~03H）。運
行轉(zhuǎn)換子程序后的轉(zhuǎn)換數(shù)據(jù)值被放入B 中。子
程序退出后即可以對B 中數(shù)據(jù)處理。
ADC0832 芯片接口程序[匯編] ：

/*-------------------------------------------
子程序名： ADC0832子程序
編寫人： 杜洋
初寫時間： 2005年10 月10日
程序功能： 將模擬電壓量轉(zhuǎn)換成數(shù)字量
實現(xiàn)方法： 串行通信。
CPU說明： MCS-51
植入說明： 占用A、B、CY、R7
-------------------------------------------*/
;以下接口定義根據(jù)硬件連線更改
ADCS BIT P3.5 ;使能接口
ADCLK BIT P3.4 ;時鐘接口
ADDO BIT P3.3 ;數(shù)據(jù)輸出接口（復(fù)用）
ADDI BIT P3.3 ;數(shù)據(jù)輸入接口
;以下語句在調(diào)用轉(zhuǎn)換程序前設(shè)定
MOV B,#00H ;裝入通道功能選擇數(shù)據(jù)值
;以下為ADC0832讀取數(shù)據(jù)子程序
;==== ADC0832讀數(shù)據(jù)子程序====
ADCONV:
SETB ADDI ;初始化通道選擇
NOP
NOP
CLR ADCS ;拉低/CS端
NOP
NOP
SETB ADCLK ;拉高CLK端
NOP
NOP
CLR ADCLK ;拉低CLK端,形成下降沿
MOV A,B
MOV C,ACC.1 ;確定取值通道選擇
MOV ADDI,C
NOP
NOP
SETB ADCLK ;拉高CLK端
NOP
NOP
CLR ADCLK ;拉低CLK端,形成下降沿2
MOV A,B
MOV C,ACC.0 ;確定取值通道選擇
MOV ADDI,C
NOPNOP
SETB ADCLK ;拉高CLK端
NOP
NOP
CLR ADCLK ;拉低CLK端,形成下降沿3
SETB ADDI
NOP
NOP
MOV R7,#8 ;準(zhǔn)備送下后8個時鐘脈沖
AD_1:
MOV C,ADDO ;接收數(shù)據(jù)
MOV ACC.0,C
RL A ;左移一次
SETB ADCLK
NOP
NOP
CLR ADCLK ;形成一次時鐘脈沖
NOP
NOP
DJNZ R7,AD_1 ;循環(huán)8次
MOV C,ADDO ;接收數(shù)據(jù)
MOV ACC.0,C
MOV B,A
MOV R7,#8
AD_13:
MOV C,ADDO ;接收數(shù)據(jù)
MOV ACC.0,C
RR A ;左移一次
SETB ADCLK
NOP
NOP
CLR ADCLK ;形成一次時鐘脈沖
NOP
NOP
DJNZ R7,AD_13 ;循環(huán)8次
CJNE A,B,ADCONV ;數(shù)據(jù)校驗
SETB ADCS ;拉高/CS端
CLR ADCLK ;拉低CLK端
SETB ADDO ;拉高數(shù)據(jù)端,回到初始狀態(tài)
RET
;====子程序結(jié)束====